Hi Prabhu,

Create data validation in P1 which lists two words (Absolute, In Lakhs)

This goes in the sheet module.

Right click on tab name > View code and paste this code there.

Code:
Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    
    If Target.Address(0, 0) <> "P1" Then Exit Sub
    
    Dim rngNumbers      As Range
    Dim strAddr         As String
    
    Set rngNumbers = Intersect(Me.UsedRange, Range("D:I")).SpecialCells(2, 1) 'adjust the range
    strAddr = rngNumbers.Address(0, 0)
    
    Const ConversionNum As Long = 100000
    
    Select Case Target.Value
        Case "Absolute"
            rngNumbers = Evaluate("if(isnumber(" & strAddr & "),if(" & strAddr & "<>0," & strAddr & "*" & ConversionNum & "," & strAddr & ")," & strAddr & ")")
            rngNumbers.NumberFormat = """Rs. ""_(* #,##0.00_);""Rs. ""_(* (#,##0.00);_(* "" - ""??_);_(@_)"
        Case "In Lakhs"
            rngNumbers = Evaluate("if(isnumber(" & strAddr & "),if(" & strAddr & "<>0," & strAddr & "/" & ConversionNum & "," & strAddr & ")," & strAddr & ")")
            rngNumbers.NumberFormat = """Rs. ""_(* #,##0.00_)"" Lakhs"";""Rs. ""_(* (#,##0.00)"" Lakhs"";_(* ""-""??_);_(@_)"
    End Select
    
End Sub
Change the value in P1, the code will adjust the figures what you select in P1