Transpose 2 column [Key, values] list to mulit column [unique Key, Value1, value2, value3, ......] list

[sandy666]

you can try Power Query (excel 2016 and up)
simple version:

let
    Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    Type = Table.TransformColumnTypes(Source,{{"Values", type text}}),
    GR = Table.Group(Type, {"Code"}, {{"GrBy", each Table.Transpose(Table.FromList([Values]))}}),
    Exp = Table.ExpandTableColumn(GR, "GrBy", {"Column1", "Column2", "Column3", "Column4"}, {"Column1", "Column2", "Column3", "Column4"}),
    Type2 = Table.TransformColumnTypes(Exp,{{"Column1", type number}, {"Column2", type number}, {"Column3", type number}, {"Column4", type number}})
in
    Type2

	A	B	C	D	E	F	G	H	I
1	Code	Values			Code	Column1	Column2	Column3	Column4
2	1001	2101			1001	2101	5205	2605	9285
3	1001	5205			2604	4256	7458	3555
4	1001	2605
5	1001	9285
6	2604	4256
7	2604	7458
8	2604	3555

[p45cal]

you can try Power Query (excel 2016 and up)simple version:

Doesn't this assume a max of 4 repeated codes?
I was waiting for the OP to come back before posting.
I did a PQ offering. A bit convoluted (I'm sure you can streamline it):
The query:

let
    Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    #"Grouped Rows" = Table.Group(Source, {"Code"}, {{"grp", each _, type table [Code=number, Values=number]}}),
    #"Invoked Custom Function" = Table.Combine(Table.AddColumn(#"Grouped Rows", "fnTranspose2", each fnTranspose2([grp]))[fnTranspose2])
in
    #"Invoked Custom Function"

The called function named fnTranspose2:

(tbl)=> [AddIndx = Table.AddIndexColumn(tbl, "Index", 1, 1, Int64.Type),
    AddPrefix = Table.TransformColumns(AddIndx, {{"Index", each "Value" & Text.From(_), type text}}),
    TakeColms = Table.ReorderColumns(AddPrefix,{"Index", "Code", "Values"}),
    Result = Table.Pivot(TakeColms, List.Distinct(TakeColms[Index]), "Index", "Values", List.Sum)][Result]

Also a formula approach:
In one cell (eg. cell F8):
=UNIQUE(Table1[Code])
In the cell to the right:
=TRANSPOSE(FILTER(Table1[Values],Table1[Code]=F8))
copied down as far as necessary. F8 is the address of that cell to the right.

[ganesannv]

it works. Let me try for more data.
Thanks