Thinking About Using VBA's IsNumeric Function? Read this first.
I have posted the following many times over the last 10 years or so in responding to old newsgroup and current forum questions. I decided to post it here for all to see.
I usually try and steer people away from using IsNumeric to "proof" supposedly numeric text. Consider this (also see note below):
Code:
ReturnValue = IsNumeric("($1,23,,3.4,,,5,,D56$)$$$$$$$")
Most people would not expect THAT to return True. IsNumeric has some "flaws" in what it considers a proper number and what most programmers are looking for.
I had a short tip published by Pinnacle Publishing in their Visual Basic Developer magazine that covered some of these flaws. Originally, the tip was free to view but is now viewable only by subscribers.. Basically, it said that IsNumeric returned True for things like -- currency symbols being located in front or in back of the number as shown in my example (also applies to plus, minus and blanks too); numbers surrounded by parentheses as shown in my example (some people use these to mark negative numbers); numbers containing any number of commas before a decimal point as shown in my example; numbers in scientific notation (a number followed by an upper or lower case "D" or "E", followed by a number equal to or less than 307 -- the maximum power of 10 in VB); and Octal/Hexadecimal numbers (&H for Hexadecimal, &O or just & in front of the number for Octal).
NOTE:
======
In the above example and in the referenced tip, I refer to $ signs and commas and dots -- these were meant to refer to your currency, thousands separator and decimal point symbols as defined in your local settings -- substitute your local regional symbols for these if appropriate.
As for your question about checking numbers, here are two functions that I have posted in the past for similar questions..... one is for digits only and the other is for "regular" numbers (the code is simple enough that it can be pulled from the function "housing" and used directly inside your own code):
Code:
Function IsDigitsOnly(Value As String) As Boolean
IsDigitsOnly = Len(Value) > 0 And Not Value Like "*[!0-9]*"
End Function
Function IsNumber(ByVal Value As String) As Boolean
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9.]*" And Not Value Like "*.*.*" And Len(Value) > 0 And Value <> "."
End Function
Here are revisions to the above functions that deal with the local settings for decimal points (and thousand's separators) that are different than used in the US (this code works in the US too, of course).
Code:
Function IsNumber(ByVal Value As String) As Boolean
Dim DP As String
' Get local setting for decimal point
DP = Format$(0, ".")
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9" & DP & "]*" And Not Value Like "*" & _
DP & "*" & DP & "*" And Len(Value) > 0 And Value <> DP
End Function
I'm not as concerned by the rejection of entries that include one or more thousand's separators, but we can handle this if we don't insist on the thousand's separator being located in the correct positions (in other words, we'll allow the user to include them for their own purposes... we'll just tolerate their presence).
Code:
Function IsNumber(ByVal Value As String) As Boolean
Dim DP As String
Dim TS As String
' Get local setting for decimal point
DP = Format$(0, ".")
' Get local setting for thousand's separator
' and eliminate them. Remove the next two lines
' if you don't want your users being able to
' type in the thousands separator at all.
TS = Mid$(Format$(1000, "#,###"), 2, 1)
Value = Replace$(Value, TS, "")
' Leave the next statement out if you don't
' want to provide for plus/minus signs
If Value Like "[+-]*" Then Value = Mid$(Value, 2)
IsNumber = Not Value Like "*[!0-9" & DP & "]*" And Not Value Like "*" & _
DP & "*" & DP & "*" And Len(Value) > 0 And Value <> DP
End Function
Application.IsNumber( ) is an alternative to IsNumeric( ))
Thanks for these ideas, Rick. - I just thought I would mention that, as I passed this Blog post on just now, I saw in that Thread something that might be worth mentioning here in passing, which is that Hans offered an Excel Worksheet function alternative, Application.IsNumber( ) , which seems more likely to give results closer to what most people would expect.
If I understand correctly the main difference between the two functions can be thought of approximately as
IsNumeric( ) is True if it thinks it can convert the given text into a number, whereas
Application.IsNumber( ) is more likely to be True only if the passed thing looks like a number, ( it won't , for example . convert a text into a number, even anything simple like "2" )
That is just an approximate conclusion as I have not investigated thoroughly both functions yet…
The intelligence behind IsNumeric( ) is perhaps a different one to ours, and perhaps as a compromise for efficiency does not thoroughly check for correctness, but rather looks for some allowed characters that might be used in some number formats,
( and it allows a text that has a number format,
( whereas Application.IsNumber( ) doesn’t: For example Application.IsNumber("1") is false because "1" is text )
IsNumeric("1") is True)
Alan
( Edit P.S. I geuss you will need to be in Excel or else load the Excel library in order to use Application.IsNumber( ) )
https://www.youtube.com/channel/UCnxwq2aGJRbjOo_MO54oaHA
https://eileenslounge.com/viewtopic.php?p=326972#p326972
https://eileenslounge.com/viewtopic.php?p=326853#p326853
https://eileenslounge.com/viewtopic.php?p=326446#p326446
https://eileenslounge.com/viewtopic.php?f=27&t=41986
https://eileenslounge.com/viewtopic.php?p=325610#p325610
https://eileenslounge.com/viewtopic.php?p=325609#p325609
https://eileenslounge.com/viewtopic.php?p=325605#p325605
https://eileenslounge.com/viewtopic.php?p=325548#p325548
https://eileenslounge.com/viewtopic.php?p=316441#p316441
https://eileenslounge.com/viewtopic.php?p=324736#p324736
https://eileenslounge.com/viewtopic.php?p=324990#p324990
https://eileenslounge.com/viewtopic.php?f=27&t=41937&p=325485#p325485
https://eileenslounge.com/viewtopic.php?p=325609#p325609
https://eileenslounge.com/viewtopic.php?p=325610#p325610
https://www.youtube.com/channel/UCnxwq2aGJRbjOo_MO54oaHA
